Recreate JSON structure from a valid JSON CLOB

I don't think this is possible using just SQL but it is possible using PL/SQL.  Below is something I quickly built that may be do some of what you are looking for that you could potentially turn into a function of some sort.  I'm not sure what kind of output you are expecting but the procedure below gives a pretty descriptive layout of the JSON.  It may not be 100% accurate but worked pretty well in my testing.  Just set the l_input variable to whatever JSON you want to "describe".

/* Formatted on 4/9/2020 8:27:16 AM (QP5 v5.354) */
DECLARE
    l_input                  CLOB := '[{  "id": "extra_verkeerslicht",
    "label": "Is de situatie gevaarlijk?",
    "test": 1,
    "arr": [1,2,3,"text",[6,7,8]],
    "answer": {
      "id": "niet_gevaarlijk",
      "label": "Niet gevaarlijk"
}}]';


    invalid_syntax           EXCEPTION;
    invalid_object           EXCEPTION;
    PRAGMA EXCEPTION_INIT (invalid_syntax, -40441);
    PRAGMA EXCEPTION_INIT (invalid_object, -40587);
    c_indent_size   CONSTANT INTEGER := 4;
    c_indent_char   CONSTANT VARCHAR2 (1) := '-';


    PROCEDURE print_obj_info (p_object json_object_t, p_indent INTEGER DEFAULT 0);


    PROCEDURE print_array_info (p_array json_array_t, p_indent INTEGER DEFAULT 0);


    FUNCTION get_type (p_element json_element_t)
        RETURN VARCHAR2
    IS
        l_type   VARCHAR2 (20);
    BEGIN
        l_type :=
            CASE
                WHEN p_element.is_array THEN 'ARRAY'
                WHEN p_element.is_object THEN 'OBJECT'
                WHEN p_element.is_number THEN 'NUMBER'
                WHEN p_element.is_boolean THEN 'BOOLEAN'
                WHEN p_element.is_string THEN 'STRING'
                WHEN p_element.is_null THEN 'NULL'
                WHEN p_element.is_date THEN 'DATE'
                WHEN p_element.is_timestamp THEN 'TIMESTAMP'
                ELSE 'unknown'
            END;


        RETURN l_type;
    END;


    PROCEDURE print_obj_info (p_object json_object_t, p_indent INTEGER DEFAULT 0)
    IS
        l_keys   json_key_list;
        l_type   VARCHAR2 (20);
    BEGIN
        l_keys := p_object.get_keys;


        FOR i IN 1 .. l_keys.COUNT
        LOOP
            l_type := get_type (p_object.get (l_keys (i)));


            DBMS_OUTPUT.put_line (
                LPAD (c_indent_char, p_indent, c_indent_char) || l_keys (i) || ': ' || l_type);


            CASE l_type
                WHEN 'OBJECT'
                THEN
                    print_obj_info (p_object.get_object (l_keys (i)), p_indent + c_indent_size);
                WHEN 'ARRAY'
                THEN
                    print_array_info (TREAT (p_object.get (l_keys (i)) AS json_array_t),
                                      p_indent + c_indent_size);
                ELSE
                    NULL;
            END CASE;
        END LOOP;
    END;


    PROCEDURE print_array_info (p_array json_array_t, p_indent INTEGER DEFAULT 0)
    IS
        l_type   VARCHAR2 (20);
    BEGIN
        FOR i IN 0 .. p_array.get_size - 1
        LOOP
            l_type := get_type (p_array.get (i));
            DBMS_OUTPUT.put_line (LPAD (c_indent_char, p_indent, c_indent_char) || l_type);


            CASE l_type
                WHEN 'OBJECT'
                THEN
                    print_obj_info (TREAT (p_array.get (i) AS json_object_t), p_indent + c_indent_size);
                WHEN 'ARRAY'
                THEN
                    print_array_info (TREAT (p_array.get (i) AS json_array_t), p_indent + c_indent_size);
                ELSE
                    NULL;
            END CASE;
        END LOOP;
    END;
BEGIN
    print_obj_info (json_object_t (l_input));
EXCEPTION
    WHEN invalid_object
    THEN
        print_array_info (json_array_t (l_input));
    WHEN invalid_syntax
    THEN
        DBMS_OUTPUT.put_line ('Invalid JSON syntax');
END;

Wow! JSON_DATAGUIDE seems to be a much better option then what I had thrown together.  Thanks for the info MaxOrgiyan-Oracle! I didn't know this feature existed, but I definitely plan on using it in the future now!